From ba5058e95e44d7e63aec73f95ea3c7ed7e311bc8 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Ctibor=20Bran=C4=8D=C3=ADk?= <ctibor@brancik.cz>
Date: Wed, 28 Jul 2021 22:37:59 +0200
Subject: Add =media-video/aravis-0.6.4

---
 media-video/aravis/Manifest            |  1 +
 media-video/aravis/aravis-0.6.4.ebuild | 85 ++++++++++++++++++++++++++++++++++
 media-video/aravis/metadata.xml        | 23 +++++++++
 3 files changed, 109 insertions(+)
 create mode 100644 media-video/aravis/Manifest
 create mode 100644 media-video/aravis/aravis-0.6.4.ebuild
 create mode 100644 media-video/aravis/metadata.xml

(limited to 'media-video')

diff --git a/media-video/aravis/Manifest b/media-video/aravis/Manifest
new file mode 100644
index 0000000..ae828b3
--- /dev/null
+++ b/media-video/aravis/Manifest
@@ -0,0 +1 @@
+DIST aravis-0.6.4.tar.gz 2972111 SHA256 591feae4d75a9f89d181efc1a7c3f07f8a5605600d6fe27bca0427820f80c0a3 SHA512 6090fd730ad9fe8e1641e48c52189e8961bf03a88cefb57135a2de985c2ca607c21b05d472a60586976aa1e05ba2121246b06b75179dd3241e1f703aad8dd7be WHIRLPOOL 34ee0ac9d7abdb9dec71870e792a201ae0ff90400818ec5edd2f48122c520683bd7898e3aa872cb4d04eed656864dc2f99e141d4429e306abac5a867de51a740
diff --git a/media-video/aravis/aravis-0.6.4.ebuild b/media-video/aravis/aravis-0.6.4.ebuild
new file mode 100644
index 0000000..fbe16e5
--- /dev/null
+++ b/media-video/aravis/aravis-0.6.4.ebuild
@@ -0,0 +1,85 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit meson xdg
+
+DESCRIPTION="Library for video acquisition using Genicam cameras"
+HOMEPAGE="https://github.com/AravisProject/aravis"
+
+if [[ ${PV} = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/AravisProject/${PN}"
+else
+	MY_P="${PN^^}_${PV//./_}"
+	SRC_URI="https://github.com/AravisProject/${PN}/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-2"
+SLOT="0"
+# FIXME: As of right now tests are always built, once that changes a USE flag
+# should be added. c.f. https://github.com/AravisProject/aravis/issues/286
+IUSE="doc fast-heartbeat gstreamer introspection packet-socket usb X"
+
+GST_DEPEND="
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+"
+BDEPEND="
+	>=dev-util/meson-0.47.0
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection )
+"
+DEPEND="
+	>=dev-libs/glib-2.34
+	dev-libs/libxml2:=
+	sys-libs/zlib:=
+	gstreamer? ( ${GST_DEPEND} )
+	packet-socket? ( sys-process/audit )
+	usb? ( virtual/libusb:1 )
+	X? (
+		${GST_DEPEND}
+		>=x11-libs/gtk+-3.12:3
+		x11-libs/libnotify
+	)
+"
+RDEPEND="${DEPEND}"
+
+if [[ ${PV} != 9999 ]]; then
+	S="${WORKDIR}/${PN}-${MY_P}"
+fi
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc documentation)
+		$(meson_use fast-heartbeat)
+		$(meson_use gstreamer gst-plugin)
+		$(meson_use introspection)
+		$(meson_use packet-socket)
+		$(meson_use usb)
+		$(meson_use X viewer)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	# Aravis appends the major and min versions (but not the patch) to it's
+	# binaries and it's folder in /usr/share. Things then end up like
+	# `arv-tool-0.6`. We use this little hack to find out the version of the
+	# current build in a way that works even for a -9999 ebuild.
+	local install_pv="$(ls ${ED}/usr/share | grep aravis- | cut -f 2 -d '-')"
+	local install_p="${PN}-${install_pv}"
+
+	# Properly place icons
+	if use X; then
+		cp -r "${ED}/usr/share/${install_p}/icons" "${ED}/usr/share" || die "Failed to copy icons"
+	fi
+
+	# Symlink versioned binaries to non-versioned
+	dosym "arv-tool-${install_pv}" "usr/bin/arv-tool"
+	dosym "arv-fake-gv-camera-${install_pv}" "usr/bin/arv-fake-gv-camera"
+	use X && dosym "arv-viewer-${install_pv}" "usr/bin/arv-viewer"
+}
diff --git a/media-video/aravis/metadata.xml b/media-video/aravis/metadata.xml
new file mode 100644
index 0000000..1b586cb
--- /dev/null
+++ b/media-video/aravis/metadata.xml
@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>lu_zero@gentoo.org</email>
+	</maintainer>
+	<maintainer type="project">
+		<email>media-video@gentoo.org</email>
+		<name>Gentoo Video project</name>
+	</maintainer>
+	<longdescription lang="en">
+		Aravis is a glib/gobject based library for video acquisition using Genicam
+		cameras. It currently implements the gigabit ethernet and USB3 protocols
+		used by industrial cameras. It also provides a basic ethernet camera
+		simulator and a simple video viewer.
+	</longdescription>
+	<use>
+		<flag name="fast-heartbeat">Enable faster heartbeat rate. </flag>
+		<flag name="gstreamer">Build the GStreamer plugin.</flag>
+		<flag name="packet-socket">Enable packet socket support.</flag>
+		<flag name="viewer">Build the GTK+-based video viewer.</flag>
+	</use>
+</pkgmetadata>
-- 
cgit v1.2.3