# Copyright 1999-2009 Tiziano Mueller
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="3"

inherit bash-completion distutils python

DESCRIPTION="CD ripper aiming for accuracy over speed."
HOMEPAGE="http://thomas.apestaart.org/morituri/trac/wiki"
SRC_URI="http://thomas.apestaart.org/download/morituri/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="alac bash-completion cdio doc +flac test wav wavpack"

PYTHON_DEPEND="*"

RDEPEND="media-sound/cdparanoia
	app-cdr/cdrdao
	media-libs/gstreamer
	alac? ( media-plugins/gst-plugins-ffmpeg )
	flac? ( media-plugins/gst-plugins-flac )
	wav? ( media-libs/gst-plugins-good )
	wavpack? ( media-plugins/gst-plugins-wavpack )
	dev-python/gst-python
	dev-python/python-musicbrainz
	dev-python/pygobject
	dev-python/pygtk
	cdio? ( dev-python/pycdio )"
DEPEND="${RDEPEND}
	doc? ( dev-python/epydoc )
	test? ( dev-python/pychecker )"

src_prepare() {
	rm py-compile
	ln -s "$(type -P true)" py-compile

	sed -i \
		-e 's|\(^SUBDIRS = .*\) doc|\1|' \
		Makefile.in || die "sed failed"
}

src_configure() {
	default
}

src_compile() {
	default

	if use doc ; then
		cd doc
		epydoc -o reference ../morituri || die "generating docs failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	rm -rf "${D}/etc"

	dodoc AUTHORS HACKING NEWS README RELEASE TODO
	use bash-completion && dobashcompletion etc/bash_completion.d/rip

	use doc && dohtml -r doc/reference/*
}