Added media-sound/musescore.

2 files changed, 64 insertions, 0 deletions

diff --git a/media-sound/musescore/Manifest b/media-sound/musescore/Manifest
new file mode 100644
index 0000000..386b4c9
--- /dev/null
+++ b/media-sound/musescore/Manifest
@@ -0,0 +1 @@
+DIST musescore-2.0.2.tar.gz 44528670 SHA256 92f35403d1cb87bdb080a18bc37b2023a998ed9a26e7f50a5b6d30dbc3c1db45 SHA512 aeb5f0c696a3c0796604c687cb3ea7303dd3536da71cf1b1e71f909cd5caa0864a879ffb19931f6ab0dc6fff854c9f2e05a64905e186b417fa954b73e3e9f08c WHIRLPOOL 87c5e64f721deec1389fcb5ae3d21536586a4ec8d3419d0f88cd2dca7cb6bab0e5df283de1253fd7407f7d6f0a8cf8a95bdd6c1877923193f7d3ea24167631a6
diff --git a/media-sound/musescore/musescore-2.0.2.ebuild b/media-sound/musescore/musescore-2.0.2.ebuild
new file mode 100644
index 0000000..54b2e6a
--- /dev/null
+++ b/media-sound/musescore/musescore-2.0.2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+inherit cmake-utils flag-o-matic
+
+DESCRIPTION="WYSIWYG Music Score Typesetter"
+HOMEPAGE="http://musescore.org/"
+SRC_URI="https://github.com/musescore/MuseScore/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="audiofile debug jack portaudio pulseaudio"
+
+RDEPEND="
+	>=dev-qt/designer-5.3.0:5
+	>=dev-qt/qtconcurrent-5.3.0:5
+	>=dev-qt/qtcore-5.3.0:5
+	>=dev-qt/qtdeclarative-5.3.0:5
+	>=dev-qt/qtgui-5.3.0:5
+	>=dev-qt/qthelp-5.3.0:5
+	>=dev-qt/qtsvg-5.3.0:5
+	>=dev-qt/qtwebkit-5.3.0:5
+	>=dev-qt/qtxmlpatterns-5.3.0:5
+	>=media-libs/alsa-lib-1.0.0
+	>=media-libs/freetype-2.5.2
+	sys-libs/zlib
+	audiofile? (
+		media-libs/audiofile
+		media-libs/libsndfile
+	)
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	"
+
+DEPEND="${RDEPEND}
+	>=dev-util/cmake-2.8.7
+	dev-qt/linguist-tools:5
+	media-sound/lame
+	virtual/pkgconfig
+	jack? ( >=media-sound/jack-audio-connection-kit-0.98.0 )
+	"
+
+S="${WORKDIR}/MuseScore-${PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_has audiofile)
+		$(cmake-utils_use_build jack)
+		$(cmake-utils_use_use portaudio)
+		$(cmake-utils_use_use pulseaudio)
+	)
+	CMAKE_BUILD_TYPE="$(usex debug DEBUG RELEASE)"
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cd "${BUILD_DIR}" || die
+	cmake-utils_src_make -j1 lrelease
+	cmake-utils_src_compile
+}