blob: 048efb5f632be1e12a5714c2ed01eb6fcbf68710 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/scribus/scribus-9999.ebuild,v 1.9 2013/09/17 15:58:17 jlec Exp $
EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE=tk
inherit cmake-utils fdo-mime multilib python-single-r1 subversion
DESCRIPTION="Desktop publishing (DTP) and layout program"
HOMEPAGE="http://www.scribus.net/"
SRC_URI=""
ESVN_REPO_URI="svn://scribus.net/trunk/Scribus"
ESVN_PROJECT=Scribus-1.5
LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="cairo debug examples graphicsmagick hunspell +minimal osg +pdf templates"
# a=$(ls resources/translations/po/scribus.*ts | sed -e 's:\.: :g' | awk '{print $2}'); echo ${a}
IUSE_LINGUAS=" af ar bg br ca cs_CZ cy da_DK de de_1901 de_CH el en_AU en_GB en_US es_ES et eu fi fr gl hu id it ja ko lt_LT nb_NO nl pl_PL pt pt_BR ru sa sk_SK sl sq sr sv th_TH tr uk zh_CN zh_TW"
IUSE+=" ${IUSE_LINGUAS// / linguas_}"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
COMMON_DEPEND="
${PYTHON_DEPS}
virtual/python-imaging[tk,${PYTHON_USEDEP}]
dev-libs/boost
dev-libs/hyphen
dev-libs/libxml2
>=dev-qt/linguist-5.0.0
>=dev-qt/qtcore-5.0.0
>=dev-qt/qtwebkit-5.0.0[printsupport]
>=dev-qt/qtwidgets-5.0.0
>=dev-qt/qtxml-5.0.0
>=dev-qt/qtdeclarative-5.0.0
>=dev-qt/linguist-tools-5.0.0
media-libs/fontconfig
media-libs/freetype:2
media-libs/lcms:2
media-libs/libpng:0
media-libs/tiff:0
net-print/cups
sys-libs/zlib[minizip]
virtual/jpeg
cairo? ( x11-libs/cairo[X,svg] )
graphicsmagick? ( media-gfx/graphicsmagick )
osg? ( dev-games/openscenegraph )
pdf? ( app-text/podofo )
hunspell? ( app-text/hunspell )"
RDEPEND="${COMMON_DEPEND}
app-text/ghostscript-gpl"
DEPEND="${COMMON_DEPEND}
virtual/pkgconfig"
src_prepare() {
cat > cmake/modules/FindZLIB.cmake <<- EOF
find_package(PkgConfig)
pkg_check_modules(ZLIB minizip zlib)
SET( ZLIB_LIBRARY \${ZLIB_LIBRARIES} )
SET( ZLIB_INCLUDE_DIR \${ZLIB_INCLUDE_DIRS} )
MARK_AS_ADVANCED( ZLIB_LIBRARY ZLIB_INCLUDE_DIR )
EOF
sed \
-e 's:\(${CMAKE_INSTALL_PREFIX}\):./\1:g' \
-i resources/templates/CMakeLists.txt || die
cmake-utils_src_prepare
subversion_src_prepare
}
src_configure() {
local lang langs
for lang in ${IUSE_LINGUAS}; do
if use linguas_${lang}; then
langs+=",${lang}"
else
sed -e "/${lang}/d" -i doc/CMakeLists.txt || die
fi
done
local mycmakeargs=(
-DHAVE_PYTHON=ON
-DPYTHON_INCLUDE_PATH=$(python_get_includedir)
-DPYTHON_LIBRARY="${EPREFIX}/usr/$(get_libdir)/lib${EPYTHON}.so"
-DWANT_NORPATH=ON
-DWANT_QTARTHUR=ON
-DWANT_QT3SUPPORT=OFF
-DGENTOOVERSION=${PVR}
-DWANT_GUI_LANG=${langs#,}
$(cmake-utils_use_with pdf PODOFO)
$(cmake-utils_use_want cairo)
$(cmake-utils_use_want graphicsmagick)
$(cmake-utils_use_want osg)
$(cmake-utils_use_want debug DEBUG)
$(cmake-utils_use_want minimal NOHEADERINSTALL)
$(cmake-utils_use_want hunspell HUNSPELL)
)
use examples || mycmakeargs+=( -DWANT_NOEXAMPLES=ON)
use templates || mycmakeargs+=( -DWANT_NOTEMPLATES=ON)
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
local lang file
for lang in ${IUSE_LINGUAS}; do
file="${ED}"/usr/share/scribus/translations/scribus.${lang}.qm
if ! use linguas_${lang} && [[ -f "${file}" ]]; then
rm "${file}" || die
fi
done
mv "${ED}"/usr/share/doc/${PN}/{en,html} || die
ln -sf html "${ED}"/usr/share/doc/${PN}/en || die
docompress -x /usr/share/doc/${PN}/en
doicon resources/icons/scribus.png
domenu scribus.desktop
}
pkg_postinst() {
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
}
pkg_postrm() {
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
}
|
